home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Sierra's Sneak Peeks 1993
/
Sierra Sneak Peeks 1993.iso
/
demo.bat
next >
Wrap
DOS Batch File
|
1993-08-25
|
7KB
|
246 lines
@echo off
goto Begin
:SetVer
echo Sierra Family Demo CD-ROM - Version 2.0 8/26/93 BC >c:\sierra\democd\version.dat
goto Welcome
rem ---------------------------------------------------------------------------
rem
rem Sierra Family Demonstration CD-ROM Menu System
rem Copyright (c) 1993 Sierra On-Line, Inc.
rem All Rights Reserved
rem
rem ---------------------------------------------------------------------------
rem SHOW.EXE Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem VTEST.EXE Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem DELAY.EXE Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem GETCPU.EXE Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem GETKEY.COM Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem MEMSIZE.EXE Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem AUTODEMO.EXE Copyright (c) 1993 Sierra On-Line, Inc., All Rights Reserved.
rem WHAT.EXE is public domain, to the best of our information.
rem
rem The individual contents of the subdirectories within the SIERRA, DYNAMIX,
rem BRGHTSTR, COKTEL, and TSN directories on this CD-ROM drive are copyrighted
rem works as indicated by the copyright notifications on the programs within
rem those directories.
rem
rem The entire CD-ROM compilation is Copyright (c) 1993 Sierra On-Line, Inc.
rem All Rights Reserved.
rem ---------------------------------------------------------------------------
rem If you're reading this comment, then obviously you like to hack around
rem in other folks code. Perhaps you had a problem running this menuing
rem system, and are trying to figure out how to make it work manually. If
rem that's the case, call our support line and let us know what problem you
rem are having. Perhaps you're just curious how it all works. If so, have
rem fun exploring!
rem ---------------------------------------------------------------------------
rem DEMONSTRATION CD-ROM COMPILATION DEVELOPMENT CREDITS:
rem
rem Designed, Produced, and Directed by Bill Crow
rem
rem Programming: Bill Crow, Robert W. Lindsley, Mark Wilden, Dan Foy, Ken Koch
rem
rem Art: Frankie Powell, Bill Crow, Mark Hood
rem
rem Text: Josh Mandel, Bill Crow
rem
rem QA: Sharon Simmons, Michael Brosius, Lynne S. Dayton, Mike Jones,
rem Roger Clendenning, Doug Wheeler, Dave Clingman, Matthew Genesi,
rem Diana Mulligan
rem
rem ---------------------------------------------------------------------------
:Begin
if "%0"=="demo" goto startok
if "%0"=="Demo" goto startok
if "%0"=="DEMO" goto startok
cls
echo.
echo To run the Sierra family demonstration CD-ROM, switch to your CD-ROM
echo drive at the dos prompt by typing the drive letter followed by a colon.
echo Then type DEMO.
echo.
echo.
goto alldone
:startok
set what=
set getkey=
set xxv=
set xxp=
set xxd=
set xxc=
set xxw=
set xxa=
menu\what e
if errorlevel 50 goto envok
echo.
echo To run the Sierra family demonstration CD-ROM, you must have at least
echo 50 bytes of free space reserved for environment variables. Currently
echo your system has only %what% bytes of free envionment space. This free
echo space is controlled by the /E option on the SHELL= command in your
echo CONFIG.SYS file. Refer to your DOS documentation for more information
echo about setting this option to create additional environment variable
echo space. If a value is already present, increase it by 50. If no value
echo is present, add the option with a value of 256.
echo.
echo.
goto alldone
:envok
menu\getcpu > NUL
if errorlevel 3 goto procok
echo.
echo The Sierra family demonstration CD-ROM requires a system with a 386 or
echo better processor. It will not run on systems with 286 processors.
echo.
echo.
goto alldone
:procok
menu\what d
if errorlevel 50 goto dosok
echo.
echo The Sierra family demonstration CD-ROM requires MS-DOS 5.0 or greater to
echo be installed on your system.
echo.
echo.
goto alldone
:dosok
set xxv=F
if "%1"=="" goto TestVesa
if "%1"=="t" goto VokCont
if "%1"=="T" goto VokCont
:TestVesa
menu\vtest
if not errorlevel 1 goto VesaOK
cls
echo.
echo In addition to the numerous product demonstrations, this Sierra Family
echo Demonstration CD-ROM also includes a high resolution, color graphics menu
echo and product information display system. A VESA compatible VGA video card
echo with at least 512k bytes of video memory is required to access the menus
echo and product displays in graphics mode. Some demos also require VESA.
echo.
echo Most new VGA video cards are VESA compatible. In many cases, this may
echo require a VESA driver to be loaded via the AUTOEXEC.BAT or CONFIG.SYS
echo file at system startup. Consult the manual that came with your video
echo card, or contact the card manufacturer for additional information.
echo.
echo For older VGA video cards that are not VESA compatible or did not ship
echo with a VESA driver, it may still be possible to achieve VESA compatibility
echo using one of the drivers available in the VESA subdirectory on this CD-ROM.
echo Take a look at the README file found in the VESA subdirectory for more
echo information about installing and configuring the appropriate VESA driver.
echo.
echo if you do not have VESA compatiblity, you can access the menus and product
echo information displays in text mode.
echo.
echo Do you want to continue in text mode? (Y/N)
menu\getkey YN
if not "%getkey%"=="Y" goto alldone
goto VokCont
:VesaOK
set xxv=T
:VokCont
menu\memsize 567
if errorlevel 1 goto memok
echo.
echo The Sierra family demonstration CD-ROM requires at least 580,000 bytes
echo (567K) of free memory for proper operation. A utility is provided to
echo create a boot diskette that will configure your system to maximize free
echo memory for running this demonstration CD-ROM
echo.
echo Do you want to run the Boot Disk Utility at this time?
menu\getkey YN
if not "%getkey%"=="Y" goto alldone
cls
bootdisk\bootdisk -c
echo.
echo.
echo.
echo Press any key to continue.
menu\getkey
goto alldone
:memok
menu\what ye
set xxd=%what%
menu\what y
set xxp=%what%
set xxc=%what%
if not "%xxp%"=="\" set xxp=%xxp%\
set what=
if exist c:\sierra\democd\version.dat goto SetVer
cls
md c:\sierra >nul
cls
md c:\sierra\democd >nul
cls
echo Sierra >c:\sierra\democd\version.dat
if exist c:\sierra\democd\version.dat goto SetVer
cls
echo It was not possible to build the required \SIERRA\DEMOCD directory on
echo the C: drive. This step is required to properly run these demonstrations.
echo This may be caused if your C: drive has no available space, or if it is
echo write protected.
echo.
echo.
echo.
goto alldone
:Welcome
%xxd%:
cd %xxc%
if "%xxv%"=="T" goto DoCp
cls
echo.
echo.
echo.
echo.
echo.
echo.
echo Copyright 1993 Sierra On-Line, Inc. All Rights Reserved
echo.
echo.
echo.
echo.
echo.
echo.
menu\delay 15
cls
goto RunDemo
:DoCp
menu\show screens\cpyright.pcx 20
menu\delay 10
if "%1"=="a" menu\AutoDemo.bat
if "%1"=="A" menu\AutoDemo.bat
:RunDemo
menu\mainmenu.bat
:alldone
set what=
set getkey=
set xxv=
set xxp=
set xxd=
set xxc=
set xxw=
set xxa=
echo.
echo.
echo.
echo.